玩转VOL（指标副图 益盟操盘手贴图 无未来

其实VOL也可以做许多的，只把它作成交量太浪费空间了。这里分享一个VOL+8的公式“玩转VOL”。在VOL指标里加载了月价托、季价托、量托、老鸭头、放量突破、出水芙蓉、多方炮和金蜘蛛8个指标。8个指标都是经过历史检验使用有效的经典指标，每一个都身手不凡，像八仙过海一样，各显神通。有八个神仙来助阵，可为你增加一份股市获胜的把握。
 用法：
 用法不用我说，看看下面的图片就应该明白了。有时，几个信号同时或相继出现，并且成交量放大，是我们优先选择的股票。
 说明：
1.几个信号同时是柱体颜色莫衷一是，一般显示其中一个信号设置的颜色，极少数情况下显示白色。
2.未经允许，不得转载和分享，包括指标、图片和文字说明。
 用法：
 用法不用我说，看看下面的图片就应该明白了。
 有时，几个信号同时或相继出现，并且成交量放大，是我们优先选择的股票。

 说明：
 几个信号同时是柱体颜色莫衷一是，一般显示其中一个信号设置的颜色，极少数情况下显示白色。

M2(0,10000,10);
 M3(0,10000,20);
 M4(0,10000,0);
 M5(0,10000,0);
 M6(0,10000,0);

 VOL:VOL#VOLUMN;
 V5:MA(VOL,5);
 V10:MA(VOL,10);
 V20:MA(VOL,20);
 LDAY1:=BARSLAST(CROSS(V5,V10));
 LDAY2:=BARSLAST(CROSS(V5,V20));
 LDAY3:=BARSLAST(CROSS(V10,V20));
 LTJ1:=(LDAY1>LDAY2 OR LDAY1=LDAY2) AND LDAY2=0 AND V10<V20;
 LTJ2:=(C>O AND REF(C,1)<REF(O,1) AND REF(C,2)>REF(O,2) AND C>REF(C,2));
 LTJ:=LTJ1 AND LTJ2;
 LTJ0:=LTJ1 AND V10>REF(V10,1);
 MA5:=MA(C,5),COLORWHITE;
 MA10:=MA(C,10),COLORCYAN;
 MA20:=MA(C,20),COLORRED;
 MA40:=MA(C,40),LINETHICK2,COLORBLUE;
 MA60:=MA(C,60),LINETHICK2,COLORGREEN;
 PDAY1:=BARSLAST(CROSS(MA5,MA60));
 PDAY2:=BARSLAST(CROSS(MA10,MA60));
 PDAY3:=BARSLAST(REF(HIGH=HHV(HIGH,PDAY2),1));
 PDAY4:=BARSLAST(CROSS(MA10,MA5));
 PDAY5:=BARSLAST(CROSS(MA5,MA10));
 A1:=PDAY1>PDAY2 AND PDAY2>PDAY3 AND PDAY3>PDAY4 AND PDAY4>PDAY5 AND PDAY5<5;
 A2:=COUNT(CROSS(MA10,MA5),PDAY2)=1;
 A3:=MA5>MA60 AND MA10>MA60;
 CSFR:=CROSS(C,MA20) AND CROSS(C,MA40) AND CROSS(C,MA60);
 YDAY1:=BARSLAST(CROSS(MA5,MA10));
 YDAY2:=BARSLAST(CROSS(MA5,MA20));
 YDAY3:=BARSLAST(CROSS(MA10,MA20));
 YJZZ:=(YDAY1=YDAY2 AND YDAY2=YDAY3 OR (YDAY1-YDAY2=1 OR YDAY2-YDAY3=1)) AND REF(MA5,2)<REF(MA10,2) AND REF(MA10,2)<REF(MA20,2) AND MA5>MA10 AND MA10>MA20 ;
 YJZZ1:=YDAY1=YDAY2 AND YDAY2=YDAY3 AND MA5>MA10 AND MA10>MA20 AND YDAY1=1;
 YJT:=YDAY1>=YDAY2 AND YDAY2=0 AND MA10<MA20;
 DAY1:=BARSLAST(CROSS(MA20,MA40));
 DAY2:=BARSLAST(CROSS(MA20,MA60));
 DAY3:=BARSLAST(CROSS(MA40,MA60));
 TJ0:=DAY1>=DAY2 AND DAY3<5;
 JZZ:=DAY1=DAY2 AND DAY2=DAY3 AND REF(MA20,1)<REF(MA40,1) AND REF(MA40,1)<REF(MA60,1) AND MA20>MA40 AND MA40>MA60;
 TJ1:=DAY1>=DAY2 AND COUNT(CROSS(MA20,MA60),DAY1)=1{AND (DAY1-DAY2)<10};
 TJ22:=C>O AND CROSS(C,REF(HHV(H,250),1)) AND VOL<V5;
 TJ3:=VOL>REF(VOL,1);
 TJ4:=MA20>MA60 AND MA40>REF(MA40,1) AND MA40<MA60;
 TJ5:=DAY1>=DAY2 AND DAY2=0 AND MA40<MA60;
 TJ:=DYNAINFO(4)>0
 AND HHV(HIGH,10)/LLV(LOW,10)<1.25
 AND REF(CLOSE,1)<(LLV(LOW,15)+(HHV(HIGH,15)-LLV(LOW,15))*0.85)
 AND CLOSE>OPEN
 AND CLOSE>=HHV(HIGH,10);
月价托:YJT,MA20-0.5,LINETHICK0,COLORYELLOW;
季价托:TJ5,MA60-0.2,LINETHICK0,COLORGREEN;
量托:LTJ0,H+0.5,LINETHICK0,COLORMAGENTA;
老鸭头:(A1 AND A2 AND A3) AND FILTER(A1 AND A2 AND A3 ,5),LINETHICK0,COLORGRAY;
放量突破:TJ,L-0.2,LINETHICK0,COLORRED,COLORWHITE;
出水芙蓉:CSFR,LINETHICK0,COLORCYAN;
多方炮:LTJ,H+0.5,LINETHICK0,COLORBLUE;
金蜘蛛:JZZ,MA60-0.2,LINETHICK0,Color70DB93;
 STICKLINE(月价托=1 AND 量托=0 ,0,VOL,8,0),COLORYELLOW;
 STICKLINE(季价托=1 AND 量托=0 ,0,VOL,8,0),COLORGREEN;
 STICKLINE(量托=1 AND 月价托=0,0,VOL,8,0),COLORMAGENTA;
 STICKLINE(老鸭头=1 AND 量托=0 ,0,VOL,8,0),COLORGRAY;
 STICKLINE(放量突破=1 AND 量托=0 ,0,VOL,8,0),COLORWHITE;
 STICKLINE(出水芙蓉=1 AND 量托=0 ,0,VOL,8,0),COLORCYAN;
 STICKLINE(多方炮=1 AND 量托=0 ,0,VOL,8,0),COLORBLUE;
 STICKLINE(金蜘蛛=1 AND 量托=0 ,0,VOL,8,0),Color70DB93;